【コマンドプロンプト】完成版！cmdでSQLの結果を変数に取得

公開日： 2014/08/31 : 最終更新日：2015/01/12 コマンドプロンプト, データベース cmd, SQL, sqlcmd, コマンドプロンプト, データベース, 変数に取得

以前、

を書きましたが、コレの完成版です。

前回のでは、ERRORLEVELに取得するというちょっと強引な方法でしたが、今回はしっかりと変数にセットできます。まぁ件数とかだけなら前回の方法でも十分ですが。。

８行目　：サーバー名
１０行目：データベース名
１２行目：結果を取得したいSQL
３５行目：FORの「tokens」をSQLで取得するカラム数にあわせる
３９行目：CALLの引数を取得カラム数分指定する

４６行目以降が取得した結果に対して、実行したい処理を記述(サンプルでは、echoで表示)

@echo off

REM #################################################
REM 変数セット
REM #################################################

REM サーバー名
SET SERVER=【サーバー名】
REM データベース名
SET DATABASE=【データベース名】
REM 実行SQL
SET SQL=SELECT TOP 3 [商品番号]^
                    ,[商品名]^
                    ,[区分番号]^
                    ,[価格],[原価]^
                    ,[商品写真]^
                    ,[販売開始日]^
                    ,[販売終了日]^
                    ,[更新日] ^
        FROM [db_Sales].[Product].[商品]

REM 行数カウント用
SET /A ROWCNT=0

REM sqlcmdコマンドの作成
SET SQLCMD=sqlcmd -S %SERVER% -E -d %DATABASE% -h -1 -s "," -Q "EXIT(set nocount on;%SQL%)"

REM #################################################
REM FOR文を使って、SQL結果1行ずつ取得
REM #################################################

REM SQLを実行し、カラムを取得する
REM ※SQLで取得するカラム数分の「tokens」を指定
FOR /F "usebackq delims=, tokens=1,2,3,4,5,6,7,8,9" %%i IN (`%SQLCMD%`) DO (

REM 1行ずつ処理する為、CALLで呼び出し(カラム数分を引数として渡す)
REM ※取得したカラムにスペースがあるときは、「"」で囲んで渡さないと引数が分割される
CALL :PROCESSING %%i %%j %%k %%l %%m %%n %%o %%p %%q
)

pause
exit

:PROCESSING
REM #################################################
REM 処理を記載
REM #################################################

REM 引数から取得
SET COL1=%1
SET COL2=%2
SET COL3=%3
SET COL4=%4
SET COL5=%5
SET COL6=%6
SET COL7=%7
SET COL8=%8
SET COL9=%9

REM 行数カウント
SET /A ROWCNT=%ROWCNT%+1

REM 1行づつ画面に出力
echo ========================
echo %ROWCNT%行目
echo ========================
echo カラム１：%COL1%
echo カラム２：%COL2%
echo カラム３：%COL3%
echo カラム４：%COL4%
echo カラム５：%COL5%
echo カラム６：%COL6%
echo カラム７：%COL7%
echo カラム８：%COL8%
echo カラム９：%COL9%
echo.

実行した結果が↓